Is it possible to use RTCZero and External Interrupts

[Yendor]

Hi,
I’m trying to get the mini ultra pro to go into low power mode and wake up every 15min and send data via LoRaWAN, I also want 2 interrupts to count pluses between sending data.

I have the code work for the timed data sending (every minute for now) but every time I add attachInterrupt(digitalPinToInterrupt(2), dripCount_interrupt_handler, LOW); to mini ultra is hanging and need to be put in bootloader mode to recover.

current running code with attachInterrupt commented out:

#include "Arduino.h"
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
#include <Wire.h>
#include <RTCZero.h>
#include <SerialFlash.h>
#include <CayenneLPP.h>
#include "SerialDebug.h"

#define Serial SerialUSB
// #define DEBUG_DISABLED true

CayenneLPP lpp(32);
RTCZero rtc;

// function
void printHex2(unsigned v);
void onEvent(ev_t ev);
void do_send(osjob_t *j);
void setup();
void loop();
void alarmMatch();

// variables
int nMin = 0;
int myCount;
u_int32_t sleepTime;
u_int32_t startTime;
u_int32_t dripCount;
u_int32_t drainCount;

// contances
const int drip_interruptPin = 5;
const int drain_interruptPin = 6;

// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 60; // 60 * 15

// This EUI must be in little-endian format, so least-significant-byte
// first. When copying an EUI from ttnctl output, this means to reverse
// the bytes. For TTN issued EUIs the last bytes should be 0xD5, 0xB3,
// 0x70.
static const u1_t PROGMEM APPEUI[8] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
void os_getArtEui(u1_t* buf)
{
  memcpy_P(buf, APPEUI, 8);
}

// This should also be in little endian format, see above.
// static const u1_t PROGMEM DEVEUI[8] = {0xbe, 0xae, 0xa7, 0x6f, 0x20, 0x54, 0xf6, 0x48};
// static const u1_t PROGMEM DEVEUI[8] = {0x48, 0xf6, 0x54, 0x20, 0x6f, 0xa7, 0xae, 0xbe};
u1_t DEVEUI[EUI64_MAC_LENGTH];
void os_getDevEui(u1_t* buf)
{
  memcpy_P(buf, DEVEUI, EUI64_MAC_LENGTH);
}

// This key should be in big endian format (or, since it is not really a
// number but a block of memory, endianness does not really apply). In
// practice, a key taken from ttnctl can be copied as-is.
// R&D Unit 1
// static const u1_t PROGMEM APPKEY[16] = {0x39, 0x26, 0xc2, 0x2f, 0x84, 0x27, 0xb4, 0x3d, 0x21, 0xae, 0x8b, 0xa4, 0xe6, 0x03, 0x04, 0x88};
// R&D Unit 3
static const u1_t PROGMEM APPKEY[16] = {0x39, 0x26, 0xc2, 0x2f, 0x84, 0x27, 0xb4, 0x3d, 0x21, 0xae, 0x8b, 0xa4, 0xe6, 0x03, 0x04, 0x88};
void os_getDevKey(u1_t* buf)
{
  memcpy_P(buf, APPKEY, 16);
}
static osjob_t sendjob;

// Pin mapping
const lmic_pinmap lmic_pins = {
  .nss = 5,
  .rxtx = LMIC_UNUSED_PIN,
  .rst = 3,
  .dio = {2, 6, LMIC_UNUSED_PIN},
};

void onEvent (ev_t ev)
{
  Serial.print(os_getTime());
  Serial.print(": ");
  switch (ev) {
    case EV_SCAN_TIMEOUT:
      Serial.println(F("EV_SCAN_TIMEOUT"));
      break;
    case EV_BEACON_FOUND:
      Serial.println(F("EV_BEACON_FOUND"));
      break;
    case EV_BEACON_MISSED:
      Serial.println(F("EV_BEACON_MISSED"));
      break;
    case EV_BEACON_TRACKED:
      Serial.println(F("EV_BEACON_TRACKED"));
      break;
    case EV_JOINING:
      Serial.println(F("EV_JOINING"));
      break;
    case EV_JOINED:
      Serial.println(F("EV_JOINED"));

      // Disable link check validation (automatically enabled
      // during join, but not supported by TTN at this time).
      LMIC_setLinkCheckMode(0);
      break;
    case EV_RFU1:
      Serial.println(F("EV_RFU1"));
      break;
    case EV_JOIN_FAILED:
      Serial.println(F("EV_JOIN_FAILED"));
      break;
    case EV_REJOIN_FAILED:
      Serial.println(F("EV_REJOIN_FAILED"));
      break;
      break;
    case EV_TXCOMPLETE:
      Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
      if (LMIC.txrxFlags & TXRX_ACK) {
        Serial.println(F("Received ack"));
        Serial.print(F("LMIC Pending Data: "));
        Serial.println(LMIC.pendTxLen);
      }
      if (LMIC.dataLen) {
        Serial.println(F("Received "));
        Serial.println(LMIC.dataLen);
        Serial.println(F(" bytes of payload"));
      }
      // Ensure all debugging messages are sent before sleep
      Serial.flush();

      // Sleep for a period of TX_INTERVAL using single shot alarm
      // Serial.print(F("Begin Epoch: "));
      // Serial.println(startTime);
      // Serial.print(F("Epoch Now: "));
      // Serial.println(rtc.getEpoch());
      sleepTime = TX_INTERVAL - (rtc.getEpoch() - startTime);
      if (sleepTime < 5) sleepTime = 5;
      if (sleepTime > TX_INTERVAL) sleepTime = TX_INTERVAL;
      // Serial.print(F("Sleeping for: "));
      // Serial.println(sleepTime);
      rtc.setAlarmEpoch(rtc.getEpoch() + sleepTime);
      rtc.enableAlarm(rtc.MATCH_YYMMDDHHMMSS);

      // USB port consumes extra current
      USBDevice.detach();
      // Enter sleep mode
      rtc.standbyMode();

      startTime = rtc.getEpoch();
      // Reinitialize USB for debugging
      USBDevice.init();
      USBDevice.attach();

      // Schedule next transmission to be immediately after this
      os_setCallback(&sendjob, do_send);
      // os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(60), do_send);
      break;
    case EV_LOST_TSYNC:
      Serial.println(F("EV_LOST_TSYNC"));
      break;
    case EV_RESET:
      Serial.println(F("EV_RESET"));
      break;
    case EV_RXCOMPLETE:
      // data received in ping slot
      Serial.println(F("EV_RXCOMPLETE"));
      break;
    case EV_LINK_DEAD:
      Serial.println(F("EV_LINK_DEAD"));
      break;
    case EV_LINK_ALIVE:
      Serial.println(F("EV_LINK_ALIVE"));
      break;
    case EV_TXSTART:
      Serial.println(F("EV_TXSTART"));
      break;
    case EV_JOIN_TXCOMPLETE:
      Serial.println(F("EV_JOIN_TXCOMPLETE: no JoinAccept"));
      break;
    default:
      Serial.println(F("Unknown event"));
      Serial.println((unsigned)ev);
      break;
  }
}

void do_send(osjob_t* j)
{
  unsigned char counter;
  float batteryVoltage;
  int adcReading;

  digitalWrite(LED_BUILTIN, HIGH);
  nMin = rtc.getMinutes();
  // Check if there is not a current TX/RX job running
  if (LMIC.opmode & OP_TXRXPEND)
  {
    Serial.println(F("OP_TXRXPEND, not sending"));
  }
  else
  {
    // ***** Battery monitor connection
    //
    // VBAT-----1M-----3M3-----GND
    //              |
    //              ---0.1uF---GND
    //              |
    //              A5
    lpp.reset();
    adcReading = analogRead(A5);
    // Discard inaccurate 1st reading
    adcReading = 0;
    // Perform averaging
    for (counter = 10; counter > 0; counter--)
    {
      adcReading += analogRead(A5);
    }
    adcReading = adcReading / 10;
    // Convert to volts
    batteryVoltage = adcReading * (4.3 / 1023.0);

    Serial.print(F("Battery: "));
    Serial.print(batteryVoltage);
    Serial.println(F(" V"));

    Serial.print(F("Time: "));
    Serial.println(rtc.getEpoch());

    // Pack into lpp package
    lpp.addVoltage(1, batteryVoltage);
    lpp.addAnalogInput(2, batteryVoltage);

    // System time
    lpp.addUnixTime(3, rtc.getEpoch());

    // Drip and Drain Count
    lpp.addGenericSensor(4, dripCount);
    lpp.addGenericSensor(5, drainCount);

    // Sleep variable testing
    myCount++;
    lpp.addAnalogInput(6, myCount);

    // Prepare upstream data transmission at the next possible time.
    LMIC_setTxData2(1, lpp.getBuffer(), lpp.getSize(), 0);
    Serial.println(F("Packet queued"));
  }
  // Next TX is scheduled after TX_COMPLETE event.

  digitalWrite(LED_BUILTIN, LOW);
}

void setDevEui(unsigned char* buf)
{
  Wire.begin();
  Wire.beginTransmission(EUI64_CHIP_ADDRESS);
  Wire.write(EUI64_MAC_ADDRESS);
  Wire.endTransmission();
  Wire.requestFrom(EUI64_CHIP_ADDRESS, EUI64_MAC_LENGTH);

  // Format needs to be little endian (LSB...MSB)
  while (Wire.available())
  {
    *buf-- = Wire.read();
  }
}

void dripCount_interrupt_handler()
{
  // detachInterrupt(digitalPinToInterrupt(drain_interruptPin));
  dripCount++;
  // attachInterrupt(digitalPinToInterrupt(drip_interruptPin), dripCount_interrupt_handler, LOW);
}

void setup()
{
  int count;
  unsigned char pinNumber;

  // ***** Put unused pins into known state *****
  pinMode(0, INPUT_PULLUP);
  pinMode(1, INPUT_PULLUP);

  // D7-D13, A0(D14)-A5(D19), SDA(D20), SCL(D21), MISO(D22)
  for (pinNumber = 7; pinNumber <= 22; pinNumber++)
  {
    pinMode(pinNumber, INPUT_PULLUP);
  }
  // RX_LED (D25) & TX_LED (D26) (both LED not mounted on Mini Ultra Pro)
  pinMode(25, INPUT_PULLUP);
  pinMode(26, INPUT_PULLUP);
  // D30 (RX) & D31 (TX) of Serial
  pinMode(30, INPUT_PULLUP);
  pinMode(31, INPUT_PULLUP);
  // D34-D38 (EBDG Interface)
  for (pinNumber = 34; pinNumber <= 38; pinNumber++)
  {
    pinMode(pinNumber, INPUT_PULLUP);
  }
  // ***** End of unused pins state initialization *****

  pinMode(LED_BUILTIN, OUTPUT);

  // Interrupts
  // pinMode(2, INPUT_PULLUP);
  // attachInterrupt(digitalPinToInterrupt(2), dripCount_interrupt_handler, LOW);

  setDevEui(&DEVEUI[EUI64_MAC_LENGTH - 1]);
  while (!Serial && millis() < 10000);
  Serial.begin(115200);
  Serial.println(F("Starting"));
  Serial.print(F("DEVEUI: "));

  for (count = EUI64_MAC_LENGTH; count > 0; count--)
  {
    Serial.print("0x");
    if (DEVEUI[count - 1] <= 0x0F) Serial.print("0");
    Serial.print(DEVEUI[count - 1], HEX);
    Serial.print(" ");
  }
  Serial.println();

  // Initialize serial flash
  SerialFlash.begin(4);
  // Put serial flash in sleep
  SerialFlash.sleep();

  // Initialize RTC
  rtc.begin();
  // Use RTC as a second timer instead of calendar
  // rtc.setEpoch(0);
  rtc.setTime(0, 0, 0);
  rtc.setDate(9, 10, 20);
  startTime = rtc.getEpoch();

  // LMIC init
  os_init();
  // Reset the MAC state. Session and pending data transfers will be discarded.
  LMIC_reset();
  LMIC_setClockError(MAX_CLOCK_ERROR * 1 / 100);

  // Start job (sending automatically starts OTAA too)
  do_send(&sendjob);
}

void loop() {
  os_runloop_once();
}

void alarmMatch()
{

}

[LIM PHANG MOH]

Hi Yendor,
The SAMD21 pin driving clock is disabled by default during sleep. This is badly implemented in the SAMD21 core at the beginning because they didn’t think much about using the external interrupt during sleep. So, since then they have patched this up using a low power library written by them here. Hope that helps.

[Yendor]

Thanks for the reply,
I was just about to post a update, anyway I did up a test program and it works but I do get a unrecognised device for the USB when I run this code. But still unable to run the full code with out it crashing when adding the interrupts.

working test code:

#include <RTCZero.h>

#define Serial SerialUSB

void interrupt_handler();

const byte button = 5;
const int32_t TX_INTERVAL = 5;
bool ledIsOn = false;
int32_t buttonCount;
int32_t startTime;
int32_t sleepTime;

RTCZero rtc;

void setup() {
  rtc.begin();
  rtc.setEpoch(0);
  // pinMode(button, INPUT_PULLUP);
  pinMode(digitalPinToInterrupt(button), INPUT_PULLUP);
  pinMode(LED_BUILTIN, OUTPUT);
  Serial.begin(115200);
  // delay(5000);
  Serial.println(F("Adding Interrupt"));
  // delay(250);
  attachInterrupt(button, interrupt_handler, LOW);
  Serial.println(F("Testing Interrupt"));
  // delay(250);
}

void loop() {
  startTime = rtc.getEpoch();

  sleepTime = TX_INTERVAL - (rtc.getEpoch() - startTime);
  if (sleepTime < 1) sleepTime = 1;
  if (sleepTime > TX_INTERVAL) sleepTime = TX_INTERVAL;
  rtc.setAlarmEpoch(rtc.getEpoch() + sleepTime);
  rtc.enableAlarm(rtc.MATCH_YYMMDDHHMMSS);
  // Serial.println(F("Now going to sleep"));
  Serial.flush();
  rtc.standbyMode();
  // Serial.println(F("I am awake"));
  digitalWrite(LED_BUILTIN, ledIsOn = !ledIsOn);
}

void interrupt_handler() {
  // Serial.println(F("Interruption triggered"));
  digitalWrite(LED_BUILTIN, ledIsOn = !ledIsOn);
}

can you suggest any thing else that maybe causing the crash or how to trap the error?

Regards

[Yendor]

Ok I think I found it, I was using pin 5 and 6 for the interrupts, but 2, 3, 5 and 6 are used for the radio. Changed to 10 and 11 and its not crashing anymore.

Thanks for your time.

[Author]

Posts